BoardSupportPackageF405 < MecrispCube

%DASHBOARD{ section="dashboard_start" }%
%DASHBOARD{ section="banner"
 image="%PUBURLPATH%/MecrispCube/BoardSupportPackageF405/feather-stm32f405-head.jpg"
 title="Board Support Package for the Adafruit Feather !STM32F405 Board"
 titlestyle="color:#F00000;"
}%
%DASHBOARD{ section="box_start" title="Intro" width="485" height="200"}%
The board support package for the Adafruit Feather !STM32F405 Board is restricted to the J1 and J3 pin header and the onboard LEDs and switches (buttons). The !STM32F405 has much more capabilities then 11 digital I/O pins, 6 analog input pins, UART, SPI, and !I2C interfaces. But if you want to use the more advanced features you can use the !CubeMX to create source code for the internal peripherals. This project wants to show how to use the Cube Ecosystem for a Forth system (or vice versa) and can't implement all features and possibilities the !STM32F405 has. It is a good starting point for your project.
%DASHBOARD{ section="box_end" }%
%DASHBOARD{ section="box_start" title="Contents" width="460" height="200"}%
%TOC%
%DASHBOARD{ section="box_end" }%
%DASHBOARD{ section="box_start"  width="992" height="600" }%
---+ Overview

   * [[MicroSdBlocks][microSD and internal Flash mass storage]] for blocks and FAT filesystem.
      * Internal Flash drive 2 !MiB
      * [[MicroSdBlocks#Filesystem_API][Filesystem API]]
      * [[MicroSdBlocks#UNIX_like_Shell_Commands][UNIX like Shell commands]]
   * Digital and analog pins
      * LEDs: LED1 (red), NeoPixel (RGB)
      * Digital port pins: D0 to D15 (D8 !NeoPixel, internal)
      * Analog port pins: A0 to A6 (A6 battery voltage, internal)
      * PWM: 
         * TIM3: D5, D6
         * TIM4: D9, D10, D14, D15
      * Input capture TIM2: A1
      * Output compare TIM2: D0, D1<br>
      * EXTI: D11, D12, D13
   * UART: D0 RX, D1 TX
   * SPI: D2 SCK, D3 MISO, D4 MOSI (e.g. for display, memory)
   * !I2C: D14 SDA, D15 SCL (external peripherals e.g. pressure)
 
   * OLED Feather Wing
      * Switches: SW1 (button A, D9), SW2 (button B, D6), SW3 (button C, D5)
      * !I2C: D14 SDA, D15 SCL 

Defaults: Digital port pins D1, D5, D6, D9 to D13 are inputs; D0 (UART_RX) is input with 100 kOhm pull-up resistor; D14 (SDA) and D15 (SCL) are open drain outputs with 10 kOhm pull-up resistors; D5, D6, and D9 with internal pull-ups (for the push buttons). 
%DASHBOARD{ section="box_end" }%

%DASHBOARD{ section="box_start"  width="992" height="600" }%
---+ Board Support Words

<pre>
led1!        ( n -- )    sets LED1 (red)
led1@        ( -- n )    gets LED1 (red)

neopixel!    ( rgb -- )  sets the neopixel RGB led ($ff0000 red, $00ff00 green, $0000ff blue)

switch1?     ( -- n )    gets switch1 (button A), closed=TRUE
switch2?     ( -- n )    gets switch2 (button B), closed=TRUE
switch3?     ( -- n )    gets switch3 (button C), closed=TRUE

dport!       ( n -- )    sets the digital output port (D0=bit0 .. D15=bit15).
dport@       ( -- n )    gets the digital input/output port (D0=bit0 .. D15=bit15).
dpin!        ( n a -- )  sets the digital output port pin a (D0=0 .. D15=15, A0=16 .. A6=23)
dpin@        ( a -- n )  gets the digital input/output port pin a
dmod         ( u a -- )  sets the pin mode: 0 in, 1 in pull-up, 2 in pull-down, 3 out push pull, 4 out open drain, 
                                            5 out push pull PWM, 6 input capture, 7 output compare, 8 I2C, 9 USART, 10 analog

EXTImod      ( u a -- )  Sets for pin a (D11, D12, D13) the EXTI mode u: 0 rising, 1 falling, 2 both edges, 3 none
EXTIwait     ( u a -- )  Wait for EXTI interrupt on pin a (D11, D12, D13), timeout u in [ms]

pwmpin!      ( u a -- )  sets the digital output port pin a (D5=5, D6=6, D9=9, D10=10, D14=14, and D15=15) to a PWM value u (0..1000).
                           Default frequency is 1 kHz, TIMER3/TIMER4
pwmprescale  ( u --  )   Sets the PWM prescale for TIMER3/TIMER4. 42 kHz / prescale, default 42 -> PWM frequency 1 kHz

ICOCprescale ( u -- )    Sets the input capture / output compare prescale for TIMER2. default 42 -> 42 MHz / 42 = 1 MHz, timer resolution 1 us
ICOCperiod!  ( u -- )    Sets the input capture / output compare (TIMER2) period. default $FFFFFFFF (4'294'967'295). 
                         When the up counter reaches the period, the counter is set to 0. 
                         For prescale 32 the maximum time is about 1 h 11 m
ICOCcount!   ( -- u )    Sets the input capture / output compare counter for TIMER2
ICOCcount@   ( u -- )    Gets the input capture / output compare counter for TIMER2
ICOCstart    ( -- )      Starts the ICOC period
ICOCstop     ( -- )      Stops the ICOC period
OCmod        ( u a -- )  Sets for pin a (D0, D1) the Output Compare mode u: 0 frozen, 1 active level on match, 
                           2 inactive level on match, 3 toggle on match, 4 forced active, 5 forced inactive
    
OCstart      ( u a -- )  Starts the output compare mode for pin a with pulse u
OCstop       ( a -- )    Stops output compare for pin a
ICstart      ( u -- )    Starts input capture u: 0 rising edge, 1 falling edge, 2 both edges
ICstop       ( -- )      Stops input capture

waitperiod   ( -- )      wait for the end of the TIMER2 period
OCwait       ( a -- )    wait for the end of output capture on pin a
ICwait       ( u -- u )  wait for the end of input capture with timeout u, returns counter u

apin@        ( a -- u )  gets the analog input port pin (A0=0 .. A6=6). Returns a 12 bit value (0..4095) 
</pre>
%DASHBOARD{ section="box_end" }%

%DASHBOARD{ section="box_start"  width="992" height="520" }%
---+ Using the Digital Port Pins (Input and Output)

Set 8 port pins to push/pull output
<pre>
3 15 dmod   \ set D15 (SCL) to Output
3 5  dmod   \ set D5 to Output
3 6  dmod   \ set D6 to Output
3 9  dmod   \ set D9 to Output
3 10 dmod   \ set D10 to Output
3 11 dmod   \ set D11 to output
3 12 dmod   \ set D12 to output
3 13 dmod   \ set D13 to output
</pre>

remap D15, D5, ..  D13
<pre>
create port-map 15 , 5 , 6 , 9 , 10 , 11 , 12 , 13 ,

: pin ( n -- n )  \ gets the Dx pin number
  cells port-map + @
;
</pre>

 <table>
  <tr>
    <td>
<pre>
: left ( -- ) 
  7 0 do
    1 i pin dpin! 
    100 osDelay drop  
    0 i pin dpin!
  loop 
;
</pre>
    </td>
    <td>
<pre>
: right ( -- )
  8 1 do  
    1 8 i - pin dpin! 
    100 osDelay drop  
    0 8 i - pin dpin!
  loop 
;
</pre>
    </td>
    <td>
<pre>
: knigthrider ( -- )
  begin 
    left right 
    key? 
  until    \ key pressed
  0 0 dpin!
  key drop     \ eat key
;
</pre>
    </td>
  </tr>
</table> 

Use the port pins on the lower row:
<pre>
3 16 dmod   \ set A0 to Output
3 17 dmod   \ set A1 to Output
3 18 dmod   \ set A2 to Output
3 19 dmod   \ set A3 to Output
3 20 dmod   \ set A4 to Output
3 21 dmod   \ set A5 to output
3 2 dmod    \ set D2 (SCK) to output
3 4 dmod    \ set D4 (MOSI) to output
</pre>

remap D15, D5, ..  D13
<pre>
create port-map 16 , 17 , 18 , 19 , 20 , 21 , 2 , 4 ,
</pre>

%DASHBOARD{ section="box_end" }%

%DASHBOARD{ section="box_start"  width="992" height="650" }%
---+ Using the ADC (Analog Input Pins)

---++ Control the Neopixel

=apin@ ( a -- u )= returns the ADC value (12 bit, 0 .. 4095) from one of the analog pins A0 to A5 (0 .. 5). Here I use the A0 to control the neopixel blue led brightness.
<pre>
: neo-blue ( -- ) 
  begin
    0 apin@ 16 /  neopixel! 
    10 osDelay drop
  key? until 
  key drop
;
</pre>

---++ Control the Knightrider Pace

=apin@ ( a -- u )= returns the ADC value (12 bit, 0 .. 4095) from one of the analog pins A0 to A5 (0 .. 5). Here I use the A0 to control the delay.

 <table>
  <tr>
    <td>
<pre>
: left ( -- ) 
  7 0 do
    1 i pin dpin! 
    0 apin@ 10 / osDelay drop  \ delay depends on A0
    0 i pin dpin!
  loop 
;
</pre>
    </td>
    <td>
<pre>
: right ( -- )
  8 1 do  
    1 8 i - pin dpin! 
    0 apin@ 10 / osDelay drop  \ delay depends on A0
    0 8 i - pin dpin!
  loop 
;
</pre>
    </td>
  </tr>
</table> 



%DASHBOARD{ section="box_end" }%

%DASHBOARD{ section="box_start"  width="992" height="400" }%
---+ Using the PWM (Analog Output Pins)

Six port pins are supported so far. 
The 16 bit timers TIM3 (D5 and D6) and TIM4 (D9, D10, D14, and D15) are used for the timebase, time resolution is 1 us (42 MHz !SysClk divided by 42). The PWM scale is from 0 (0 % duty cycle) to 1000 (100 % duty cycle), this results in a PWM frequency of 1 kHz. If you need higher PWM frequencies, decrease the divider and/or the scale.

PWM port pins: D5 (!TIM3CH2), D6 (!TIM3CH1), D9 (!TIM4CH3), D10 (!TIM4CH4), D14 (!TIM4CH2), and D15 (!TIM4CH1).

Simple test program to set brightness of a LED on pin D6 with a potentiometer on A0. Default PWM frequency is 1 kHz (prescaler set to 42). You can set the prescale with the word =pwmprescale= from 42 kHz (value 1) down to 0.5 Hz (64000).
<pre>
5 6 dmod   \ set D6 to PWM

: pwm ( -- )
  begin 
    0 apin@  4 /  6 pwmpin!
    10 osDelay drop
    key? 
  until
  key drop
;
</pre>


---++ Control an RC Servo

https://en.wikipedia.org/wiki/Servo_(radio_control): 
The control signal is a digital PWM signal with a 50 Hz frame rate. Within each 20 ms timeframe, an active-high digital pulse controls the position. The pulse nominally ranges from 1.0 ms to 2.0 ms with 1.5 ms always being center of range. Pulse widths outside this range can be used for "overtravel" - moving the servo beyond its normal range. 

A servo pulse of 1.5 ms width will typically set the servo to its "neutral" position (typically half of the specified full range), a pulse of 1.0 ms will set it to 0°, and a pulse of 2.0 ms to 90° (for a 90° servo). The physical limits and timings of the servo hardware varies between brands and models, but a general servo's full angular motion will travel somewhere in the range of 90° – 180° and the neutral position (45° or 90°) is almost always at 1.5 ms. This is the "standard pulse servo mode" used by all hobby analog servos. 

The BSPs default PWM frequency is 1 kHz, 50 Hz is 20 times slower. The divider is therefore 42 * 20 = 840. 
|   0° | 1 ms   | 50  | 
|  45° | 1.5 ms | 75  | 
|  90° | 2 ms   | 100 | 
| 180° | 3 ms   | 150 | 
| 270  | 4 ms   | 200 | 

|   0° | 1 ms   | 50  | 
|  90° | 1.5 ms | 75  | 
| 180° | 2 ms   | 100 | 
| 270° | 2.5 ms | 150 | 
 


<pre>
840 pwmprescale 
5 5 dmod   \ set D5 to PWM
5 6 dmod   \ set D6 to PWM
5 9 dmod   \ set D9 to PWM
5 10 dmod  \ set D10 to PWM

: servo ( u n -- ) \ u 0 .. 
;
</pre>



%DASHBOARD{ section="box_end" }%

%DASHBOARD{ section="box_start"  width="992" height="500" }%
---+ Using Input Capture and Output Compare

---++ Time Base

Default timer resolution is 1 us. The 32 bit TIMER2 is used as time base for Input Capture / Output Compare. For a 5 s period 5'000'000 cycles are needed. 
All channels (input capture / output compare) use the same time base.
<pre>
: period ( -- )
  5000000 ICOCperiod! \ 5 s period
  ICOCstart
  begin
     waitperiod
     cr .time
  key? until
  key drop 
;
</pre>


---++ Output Compare
Output compare TIM2: D0, D1

<pre>
7 0 dmod  \ output compare for D0
7 1 dmod  \ output compare for D1

: oc-toggle ( -- )
  5000000 ICOCperiod! \ 5 s period
  ICOCstart
  3 0 OCmod  1000000 0 OCstart \ toggle D0 after 1 s
  3 1 OCmod  2000000 1 OCstart \ toggle D1 after 2 s
  begin
     waitperiod
     cr .time
  key? until
  key drop 
;
</pre>

When you abort (hit any key) the program, the timer still runs and controls the port pins. To stop the port pins:
<pre>
0 OCstop  1 OCstop  
</pre>

Or change the prescale to make it faster or slower:
<pre>
1 ICOCprescale
</pre>


---++ Input Capture

This sample program measures the time between the edges on port A1. if no event occurs within 2 seconds, "timeout" is issued. Hit any key to abort program.
<pre>
: ic-test ( -- )
  6 17 dmod \ input capture on A1
  ICOCstart
  2 ICstart  \ both edges
  ICOCcount@ ( -- count )
  begin
    2000 \ 2 s timeout
    ICwait ( -- old-capture capture ) 
    cr
    dup 0= if
      ." timeout" drop
    else 
      dup rot ( -- capture capture old-capture )
      - 1000 / . ." ms"
    then
  key? until
  key drop
  drop
  ICstop
;

</pre>



%DASHBOARD{ section="box_end" }%

%DASHBOARD{ section="box_start"  width="992" height="400" }%
---+ Using EXTI line

D11, D12, and D13 can be used as an EXTI line. EXTIs are external interrupt lines, D13 uses EXTI1 (EXTI Line1 interrupt), D12 EXIT2, and D11 EXTI3. 

<pre>
: exti-test ( -- )
  2 11 EXTImod \ both edges on D11
  begin
    2000 11 EXTIwait \ wait for edge on D11 with 2 s timeout
    cr
    0= if
      11 dpin@ if
        ." rising edge"
      else
        ." falling edge"
      then 
    else
      ." timeout"
    then
  key? until
  key drop
;
</pre>


%DASHBOARD{ section="box_end" }%

%DASHBOARD{ section="box_start"  width="992" height="800" }%

---+ Pinouts
https://learn.adafruit.com/adafruit-stm32f405-feather-express/pinouts

<img src="%ATTACHURLPATH%/feather_boards_logic.jpg" alt="feather_boards_logic.jpg" width="800" height="426" />

<pre>
SCL D15, SDA D14
SCK D2, MO D4, MI D3, RX D0, TX D1
</pre>
The anlog pins can be used as digital pins too:
<pre>
A0 D16, A1 D17, A2 D18, A3 D19, A4 D20, A5 D21
</pre>

---++ Digital Pins

---+++ BOOT0 / JP1.1

---+++ RESET/ JP1.16

---+++ UART_RX / GPIO D0  / PB11 / JP1.3
   * Receive (input) pin for Serial3. Hardware USART3
   * PWM out on TIM2_CH4
   * Alternate uses: I2C2 SDA

---+++ UART_TX / GPIO D1 / PB10 / JP1.2
   * Transmit (output) pin for Serial3. Hardware USART3
   * PWM out on TIM2_CH3
   * Alternate uses: I2C2 SCL

---+++ SCK / GPIO23 D2 / PB13 / JP1.6
   * The SPI bus clock pin. Hardware SPI2
   * PWM out on TIM1_CH1N 
   * Alternate uses: I2S2 Clock, CAN2 TX

---+++ MISO / GPIO24 D3 / PB14 / JP1.4
   * The SPI bus clock pin. Hardware SPI2
   * PWM out on TIM1_CH2N
   * Alternate uses: I2S2ext SD

---+++ MOSI / GPIO25 D4 / PB15 / JP1.5
   * The SPI bus clock pin. Hardware SPI2
   * PWM out on TIM1_CH3N
   * Alternate uses: I2S2 SD

---+++ GPIO D5 / Button C / PC7 / JP3.10
   * PWM out on TIM3_CH2
   * Alternate uses: USART6 RX, I2S3 MCK

---+++ GPIO D6 / Button B / PC6 / JP3.9
   * PWM out on TIM3_CH1
   * Alternate uses: USART6 TX, I2S2 MCK

---+++ GPIO D7 / PC13 (internal)
   * Fake GPIO, not connected

---+++ NeoPixel / GPIO D8 / PC0 (internal)
   * NeoPixel 

---+++ GPIO D9 / Button A / PB8 / JP3.8
   * PWM out on TIM4_CH3
   * Alternate uses: CAN1 RX, I2C1 SCL

---+++ GPIO D10 / PB9 / JP3.7
   * PWM out on TIM4_CH4
   * Alternate uses: CAN1 TX, I2C1 SDA

---+++ GPIO D11 / PC3 / JP3.6
   * No PWM
   * Alternate uses: I2S2 SD, SPI2 MOSI

---+++ GPIO D12 / PC2 / JP3.5
   * No PWM
   * Alternate uses: I2S2ext SD, SPI2 MISO

---+++ GPIO D13 / red LED / PC1 / JP3.4
   * Connected to the red LED next to the USB jack
   * No PWM or alternate uses

---+++ SDA / GPIO D14 / PB7 / JP3.12
   * The I2C (Wire) data pin, this has a 10K pullup to 3.3V. Hardware I2C1
   * PWM out on TIM4_CH2
   * Alternate uses: USART1 RX

---+++ SCL / GPIO D15 / PB6 / JP3.11
   * the I2C (Wire) clock pin, this has a 10K pullup to 3.3V. Hardware I2C1
   * PWM out on TIM4_CH1
   * Alternate uses: USART1 TX, CAN2 TX


---++ Analog Pins

---+++ A0 / GPIO 16 / PA4 / JP1.12
   * This pin is analog input A0 (ADC12 IN4)
   * Analog output (DAC OUT1) due to having a DAC (digital-to-analog converter). You can set the raw voltage to anything from 0 to 3.3V, unlike PWM outputs this is a true analog output
   * No PWM or alternate uses

---+++ A1 / GPIO 17 / PA5 / JP1.11
   * This pin is analog input  A1 (ADC12 IN5)
   * Analog output (DAC OUT2) due to having a DAC (digital-to-analog converter). This is the second DAC, and is 'independent' of A0. You can set the raw voltage to anything from 0 to 3.3V, unlike PWM outputs this is a true analog output.
   * Alternative uses: SPI1 SCK

---+++ A2 / GPIO18 / PA6 / JP1.10
   * This pin is analog input  A2 (ADC12 IN6)
   * Alternative uses: SPI1 MISO
   * PWM out on TIM3_CH1

---+++ A3 / GPIO19 / PA7 / JP1.9
   * This pin is analog input  A3 (ADC12 IN7)
   * Alternative uses: SPI1 MOSI
   * PWM out on TIM3_CH2

---+++ A4 / GPIO20 / PC4 / JP1.8
   * This pin is analog input  A4 (ADC12 IN14)

---+++ A5 / GPIO21 / PC5 / JP1.7
   * This pin is analog input  A5 (ADC12 IN15)

---+++ A6 / PA3 (internal)
   * is also available for reading the battery voltage, see the Power Management page for instructions how


---++ SD Card / SDIO Pins

---+++ SDIO_D0 / SD_MISO / PC8 (internal)
---+++ SDIO_D1 / PC9 (internal)
---+++ SDIO_D2 / PC10 (internal)
---+++ SDIO_D3 / SD_CS / PC11 (internal)
---+++ SDIO_CLK / SD_CLK / PC12 (internal)
---+++ SDIO_CMD / SD_MOSI / PD2 (internal)
---+++ SD_DETECT / PB12 (internal)


---++ SPI Flash
---+++ FLASH_SCK / PB3 (internal)
---+++ FLASH_MISO / PB4 (internal)
---+++ FLASH_MOSI / PB5 (internal)


---++ Qwiic / STEMMA QT port

---++ USB
---+++ USB_DP / PA12
---+++ USB_DM / PA11


%DASHBOARD{ section="box_end" }%

%DASHBOARD{ section="dashboard_end" }%


-- %USERSIG{PeterSchmid - 2020-04-11}%

<a rel="license" href="http://creativecommons.org/licenses/by-sa/4.0/"><img alt="Creative Commons License" style="border-width:0" src="https://i.creativecommons.org/l/by-sa/4.0/88x31.png" /></a><br />This work by <a xmlns:cc="http://creativecommons.org/ns#" href="http://spyr.ch" property="cc:attributionName" rel="cc:attributionURL">Peter Schmid</a> is licensed under a <a rel="license" href="http://creativecommons.org/licenses/by-sa/4.0/">Creative Commons Attribution-ShareAlike 4.0 International License</a>.
Attachments
Topic attachments
I	Attachment	History	Action	Size	Date	Who
png	TEK0012.png	r1	manage	3.6 K	2020-04-16 - 14:22	PeterSchmid
jpg	feather-stm32f405-head.jpg	r1	manage	293.3 K	2021-03-02 - 11:11	PeterSchmid
jpg	feather_boards_logic.jpg	r1	manage	117.8 K	2021-04-29 - 08:56	PeterSchmid
This topic: MecrispCube > WebHome > BoardSupportPackageF405
Topic revision: r44 - 2021-05-03 - PeterSchmid